Rules for integrands of the form (((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0

1.  ∫x (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0

1:  ∫((x (((a+b ArcSinh[c x]))^n))/(d+e (x^2)))dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  e==(c^2) d, then (x/(d+e (x^2)))==(1/e)Subst[Tanh[x],x,ArcSinh[c x]](∂_x)ArcSinh[c x]

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n)Tanh[x] is integrable in closed-form.

Rule: If  e==(c^2) d ∧ n∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcSinh[c x]))^n))/(d+e (x^2)))dx  ⟶  (1/e)Subst[∫(((a+b x))^n) Tanh[x]dx,x,ArcSinh[c x]]

Program code:

Int[x_*(a_.+b_.*ArcSinh[c_.*x_])^n_./(d_+e_.*x_^2),x_Symbol] :=
  1/e*Subst[Int[(a+b*x)^n*Tanh[x],x],x,ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[n,0]

2:  ∫x (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n>0 ∧ p≠-1, then

∫x (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx
  ⟶  (((((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(2 e (p+1)))-((b c n)/(2 e (p+1)))∫(((((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))dx
  ⟶  (((((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(2 e (p+1)))-((b n (((d+e (x^2)))^p))/(2c(p+1) (((1+(c^2) (x^2)))^p)))∫(((1+(c^2) (x^2)))^(p+(1/2)))(((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[x_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(2*e*(p+1)) - 
  b*n/(2*c*(p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && GtQ[n,0] && NeQ[p,-1]

2.  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ m+2 p+3==0

1:  ∫((((a+b ArcSinh[c x]))^n)/(x (d+e (x^2))))dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  e==(c^2) d, then (1/(x (d+e (x^2))))==(1/d)Subst[(1/(Cosh[x] Sinh[x])),x,ArcSinh[c x]] (∂_x)ArcSinh[c x]

Rule: If  e==(c^2) d ∧ n∈(SuperPlus[ℤ]), then

∫((((a+b ArcSinh[c x]))^n)/(x (d+e (x^2))))dx  ⟶  (1/d)Subst[∫((((a+b x))^n)/(Cosh[x] Sinh[x]))dx,x,ArcSinh[c x]]

Program code:

Int[(a_.+b_.*ArcSinh[c_.*x_])^n_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  1/d*Subst[Int[(a+b*x)^n/(Cosh[x]*Sinh[x]),x],x,ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[n,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ m+2 p+3==0 ∧ m≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: If  m+2 p+3==0, then (((f x))^m) (((d+e (x^2)))^p)==(∂_x)(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)))/(d f (m+1)))

Basis: (∂_x)(((a+b ArcSinh[c x]))^n)==((b c n (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n>0 ∧ m+2 p+3==0 ∧ m≠-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

  ⟶  (((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(d f(m+1)))-((b c n)/(d f(m+1))∫(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^(n-1)))/(Sqrt[1+(c^2) (x^2)]))dx

  ⟶  (((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(d f(m+1)))-((b c n (((d+e (x^2)))^p))/(f(m+1)(((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1)) (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(d*f*(m+1)) - 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[e,c^2*d] && GtQ[n,0] && EqQ[m+2*p+3,0] && NeQ[m,-1]

3.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p>0

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ ((m-1)/2)∈(SuperMinus[ℤ])

1:  ∫(((((d+e (x^2)))^p) (a+b ArcSinh[c x]))/x)dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

Derivation: Inverted integration by parts

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ]), then

∫(((((d+e (x^2)))^p) (a+b ArcSinh[c x]))/x)dx  ⟶  
(((((d+e (x^2)))^p) (a+b ArcSinh[c x]))/(2 p))-((b c (d^p))/(2 p))∫(((1+(c^2) (x^2)))^(p-(1/2)))dx+d ∫ (((((d+e (x^2)))^(p-1)) (a+b ArcSinh[c x]))/x)dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])/x_,x_Symbol] :=
  (d+e*x^2)^p*(a+b*ArcSinh[c*x])/(2*p) - 
  b*c*d^p/(2*p)*Int[(1+c^2*x^2)^(p-1/2),x] + 
  d*Int[(d+e*x^2)^(p-1)*(a+b*ArcSinh[c*x])/x,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ ((m+1)/2)∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ ((m+1)/2)∈(SuperMinus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  
(((((f x))^(m+1))(((d+e (x^2)))^p) (a+b ArcSinh[c x]))/(f(m+1)))-
((b c (d^p))/(f(m+1)))∫(((f x))^(m+1))(((1+(c^2) (x^2)))^(p-(1/2)))dx-((2 e p)/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^(p-1)) (a+b ArcSinh[c x])dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcSinh[c*x])/(f*(m+1)) - 
  b*c*d^p/(f*(m+1))*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p-1/2),x] - 
  2*e*p/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^(p-1)*(a+b*ArcSinh[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && IGtQ[p,0] && ILtQ[(m+1)/2,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ]), let  u=∫(((f x))^m) (((d+e (x^2)))^p)dx, then

∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  u (a+b ArcSinh[c x])-b c∫(u/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcSinh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1+c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && IGtQ[p,0]

2:  ∫(x^m)(((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e==(c^2) d ∧ p-(1/2)∈ℤ ∧ p≠-(1/2) ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ]))

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSinh[c x])==((b c)/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[d+e (x^2)])/(Sqrt[1+(c^2) (x^2)]))==0

Note: If  p-(1/2)∈ℤ ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ])), then ∫(x^m)(((d+e (x^2)))^p)dx is an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  e==(c^2) d ∧ p-(1/2)∈ℤ ∧ p≠-(1/2) ∧ (((m+1)/2)∈(SuperPlus[ℤ])∨ ((m+2 p+3)/2)∈(SuperMinus[ℤ])), let  u=∫(x^m)(((d+e (x^2)))^p)dx, then

∫(x^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  u (a+b ArcSinh[c x])-b c ∫(u/(Sqrt[1+(c^2) (x^2)]))dx  ⟶  u (a+b ArcCosh[c x])-((b c (Sqrt[d+e (x^2)]))/(Sqrt[1+(c^2) (x^2)])) ∫(u/(Sqrt[d+e (x^2)]))dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^2)^p,x]},
  Dist[a+b*ArcSinh[c*x],u] - 
  b*c*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[SimplifyIntegrand[u/Sqrt[d+e*x^2],x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IntegerQ[p-1/2] && NeQ[p,-1/2] && (IGtQ[(m+1)/2,0] || ILtQ[(m+2*p+3)/2,0])

2.  ∫(((f x))^m)(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0

1:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ m<-1

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  e==(c^2) d ∧ n>0 ∧ m<-1, then

∫(((f x))^m)(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^(m+1))(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n))/(f(m+1)))-
((b c n(Sqrt[d+e (x^2)]))/(f(m+1)(Sqrt[1+(c^2) (x^2)])))∫(((f x))^(m+1))(((a+b ArcSinh[c x]))^(n-1))dx-(((c^2)(Sqrt[d+e (x^2)]))/((f^2)(m+1)(Sqrt[1+(c^2) (x^2)])))∫(((((f x))^(m+2)) (((a+b ArcSinh[c x]))^n))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcSinh[c*x])^n/(f*(m+1)) - 
  b*c*n/(f*(m+1))*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[(f*x)^(m+1)*(a+b*ArcSinh[c*x])^(n-1),x] - 
  c^2/(f^2*(m+1))*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[(f*x)^(m+2)*(a+b*ArcSinh[c*x])^n/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[n,0] && LtQ[m,-1]

2:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])∧ (m+2∈(SuperPlus[ℤ])∨ n==1)

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  e==(c^2) d ∧ n∈(SuperPlus[ℤ])∧ (m+2∈(SuperPlus[ℤ])∨ n==1), then

∫(((f x))^m)(Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n))/(f(m+2)))-
((b c n(Sqrt[d+e (x^2)]))/(f(m+2)(Sqrt[1+(c^2) (x^2)])))∫(((f x))^(m+1)) (((a+b ArcSinh[c x]))^(n-1))dx+((Sqrt[d+e (x^2)])/((m+2)(Sqrt[1+(c^2) (x^2)])))∫ (((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcSinh[c*x])^n/(f*(m+2)) - 
  b*c*n/(f*(m+2))*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[(f*x)^(m+1)*(a+b*ArcSinh[c*x])^(n-1),x] + 
  1/(m+2)*Simp[Sqrt[d+e*x^2]/Sqrt[1+c^2*x^2]]*Int[(f*x)^m*(a+b*ArcSinh[c*x])^n/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && IGtQ[n,0] && (IGtQ[m,-2] || EqQ[n,1])

3.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0

1:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0 ∧ m<-1

Derivation: Inverted integration by parts

Rule: If  e==(c^2) d ∧ n>0 ∧ p>0 ∧ m<-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^(m+1))(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n))/(f(m+1)))-
((2 e p)/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^(p-1)) (((a+b ArcSinh[c x]))^n)dx-((b c n (((d+e (x^2)))^p))/(f(m+1)(((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1))(((1+(c^2) (x^2)))^(p-(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n/(f*(m+1)) - 
  2*e*p/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^(p-1)*(a+b*ArcSinh[c*x])^n,x] - 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[n,0] && GtQ[p,0] && LtQ[m,-1]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p>0 ∧ m≮-1

Derivation: Inverted integration by parts

Rule: If  e==(c^2) d ∧ n>0 ∧ p>0 ∧ m≮-1, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^(m+1)) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n))/(f(m+2 p+1)))+
((2d p)/(m+2 p+1)) ∫ (((f x))^m) (((d+e (x^2)))^(p-1)) (((a+b ArcSinh[c x]))^n)dx-((b c n (((d+e (x^2)))^p))/(f (m+2 p+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1)) (((1+(c^2) (x^2)))^(p-(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n/(f*(m+2*p+1)) + 
  2*d*p/(m+2*p+1)*Int[(f*x)^m*(d+e*x^2)^(p-1)*(a+b*ArcSinh[c*x])^n,x] - 
  b*c*n/(f*(m+2*p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && GtQ[n,0] && GtQ[p,0] && Not[LtQ[m,-1]]

4:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ m+1∈(SuperMinus[ℤ])

Rule: If  e==(c^2) d ∧ n>0 ∧ m+1∈(SuperMinus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(d f(m+1)))-
(((c^2)(m+2 p+3))/((f^2)(m+1)))∫(((f x))^(m+2)) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx-((b c n (((d+e (x^2)))^p))/(f(m+1)(((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1)) (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Programcode:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(d*f*(m+1)) - 
  c^2*(m+2*p+3)/(f^2*(m+1))*Int[(f*x)^(m+2)*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n,x] - 
  b*c*n/(f*(m+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[e,c^2*d] && GtQ[n,0] && ILtQ[m,-1]

5.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ m∈ℤ

1:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ m-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Rule: If  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ m-1∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
((f(((f x))^(m-1))(((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(2 e (p+1)))-
(((f^2)(m-1))/(2e(p+1) ))∫(((f x))^(m-2))(((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n)dx-((b f n (((d+e (x^2)))^p))/(2c(p+1)(((1+(c^2) (x^2)))^p)))∫(((f x))^(m-1))(((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(2*e*(p+1)) - 
  f^2*(m-1)/(2*e*(p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n,x] - 
  b*f*n/(2*c*(p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m-1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[n,0] && LtQ[p,-1] && IGtQ[m,1]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ m∈(SuperMinus[ℤ])

Rule: If  e==(c^2) d ∧ n>0 ∧ p<-1 ∧ m∈(SuperMinus[ℤ]), then

∫ (((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
-(((((f x))^(m+1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(2 d f (p+1)))+
((m+2 p+3)/(2 d (p+1)))∫(((f x))^m)(((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n)dx+((b c n (((d+e (x^2)))^p))/(2 f (p+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1)) (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(2*d*f*(p+1)) + 
  (m+2*p+3)/(2*d*(p+1))*Int[(f*x)^m*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n,x] + 
  b*c*n/(2*f*(p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && GtQ[n,0] && LtQ[p,-1] && Not[GtQ[m,1]] && (IntegerQ[m] || IntegerQ[p] || EqQ[n,1])

6:  ∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])∧ m+2 p+1≠0

Rule: If  e==(c^2) d ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])∧ m+2 p+1≠0, then

∫(((f x))^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
((f(((f x))^(m-1)) (((d+e (x^2)))^(p+1)) (((a+b ArcSinh[c x]))^n))/(e(m+2 p+1)))-
(((f^2)(m-1))/((c^2) (m+2 p+1)))∫(((f x))^(m-2))(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx-((b f n (((d+e (x^2)))^p))/(c(m+2 p+1)(((1+(c^2) (x^2)))^p)))∫(((f x))^(m-1)) (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n-1))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  f*(f*x)^(m-1)*(d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])^n/(e*(m+2*p+1)) - 
  f^2*(m-1)/(c^2*(m+2*p+1))*Int[(f*x)^(m-2)*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n,x] - 
  b*f*n/(c*(m+2*p+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m-1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[e,c^2*d] && GtQ[n,0] && IGtQ[m,1] && NeQ[m+2*p+1,0]

2.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1

1:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1 ∧ m+2 p+1==0

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c(n+1)))

Basis: If  e==(c^2) d ∧ m+2 p+1==0, then (∂_x)((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p))==((f m (((f x))^(m-1)) (((d+e (x^2)))^p))/(Sqrt[1+(c^2) (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n<-1 ∧ m+2 p+1==0, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-((f m (((d+e (x^2)))^p))/(b c(n+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m-1))(((1+(c^2) (x^2)))^(p-(1/2)))(((a+b ArcSinh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Sqrt[1+c^2*x^2]*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m-1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[e,c^2*d] && LtQ[n,-1] && EqQ[m+2*p+1,0]

2:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1 ∧ 2p∈(SuperPlus[ℤ])∧ m+2 p+1≠0

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Basis: If  e==(c^2) d, then (∂_x)((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p))==((f m (((f x))^(m-1)) (((d+e (x^2)))^p))/(Sqrt[1+(c^2) (x^2)]))+(((c^2) (m+2 p+1) (((f x))^(m+1)) (((d+e (x^2)))^p))/(f (Sqrt[1+(c^2) (x^2)])))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n<-1 ∧ 2p∈(SuperPlus[ℤ])∧ m+2 p+1≠0, then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  

(((((f x))^m)(Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^(n+1)))/(b c(n+1)))-
((f m (((d+e (x^2)))^p))/(b c (n+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m-1))(((1+(c^2) (x^2)))^(p-(1/2)))(((a+b ArcSinh[c x]))^(n+1))dx-
((c (m+2 p+1) (((d+e (x^2)))^p))/(b f(n+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1))(((1+(c^2) (x^2)))^(p-(1/2)))(((a+b ArcSinh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Sqrt[1+c^2*x^2]*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m-1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] - 
  c*(m+2*p+1)/(b*f*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && LtQ[n,-1] && IGtQ[2*p,0] && NeQ[m+2*p+1,0] && IGtQ[m,-3]

3:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ n<-1 ∧ 2p∈ℤ ∧ p≠-(1/2)

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c(n+1)))

Basis: If  e==(c^2) d, then (∂_x)((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p))==f m (((f x))^(m-1)) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p)+(((c^2) (2 p+1) (((f x))^(m+1)) (((d+e (x^2)))^p))/(f (Sqrt[1+(c^2) (x^2)])))

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Rule: If  e==(c^2) d ∧ n<-1 ∧ 2p∈ℤ ∧ p≠-(1/2), then

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

  ⟶  (((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(b c (n+1)))-
((f m)/(b c (n+1))) ∫(((f x))^(m-1))(Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1))dx-
((c (2 p+1) )/(b f (n+1)))∫(((((f x))^(m+1)) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(Sqrt[1+(c^2) (x^2)]))dx

  ⟶  (((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^(n+1)))/(b c (n+1)))-
((f m (((d+e (x^2)))^p))/(b c (n+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m-1)) (((1+(c^2) (x^2)))^(p+(1/2))) (((a+b ArcSinh[c x]))^(n+1))dx-
((c (2 p+1) (((d+e (x^2)))^p))/(b f(n+1) (((1+(c^2) (x^2)))^p)))∫(((f x))^(m+1)) (((1+(c^2) (x^2)))^(p-(1/2))) (((a+b ArcSinh[c x]))^(n+1))dx

Program code:

(* Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_,x_Symbol] :=
  (f*x)^m*Simp[Sqrt[1+c^2*x^2]*(d+e*x^2)^p]*(a+b*ArcSinh[c*x])^(n+1)/(b*c*(n+1)) - 
  f*m/(b*c*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m-1)*(1+c^2*x^2)^(p+1/2)*(a+b*ArcSinh[c*x])^(n+1),x] - 
  c*(2*p+1)/(b*f*(n+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*Int[(f*x)^(m+1)*(1+c^2*x^2)^(p-1/2)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && EqQ[e,c^2*d] && LtQ[n,-1] && IntegerQ[2*p] && NeQ[p,-1/2] && IGtQ[m,-3] *)

3.  ∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d

1.  ∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n>0

1:  ∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n>0 ∧ m-1∈(SuperPlus[ℤ])

Rule: If  e==(c^2) d ∧ n>0 ∧ m-1∈(SuperPlus[ℤ]), then

∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  
((f(((f x))^(m-1)) (Sqrt[d+e (x^2)]) (((a+b ArcSinh[c x]))^n))/(e m))-
((b f n(Sqrt[1+(c^2) (x^2)]))/(c m(Sqrt[d+e (x^2)])))∫(((f x))^(m-1)) (((a+b ArcSinh[c x]))^(n-1))dx-(((f^2)(m-1))/((c^2) m))∫(((((f x))^(m-2)) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcSinh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcSinh[c*x])^n/(e*m) - 
  b*f*n/(c*m)*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Int[(f*x)^(m-1)*(a+b*ArcSinh[c*x])^(n-1),x] - 
  f^2*(m-1)/(c^2*m)*Int[((f*x)^(m-2)*(a+b*ArcSinh[c*x])^n)/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[n,0] && IGtQ[m,1]

2:  ∫(((x^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Basis: If  m∈ℤ, then ((x^m)/(Sqrt[1+(c^2) (x^2)]))==(1/(c^(m+1))) Subst[((Sinh[x])^m),x,ArcSinh[c x]](∂_x)ArcSinh[c x]

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n)Sinh[x] is integrable in closed-form.

Rule: If  e==(c^2) d ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(((x^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1+(c^2) (x^2)])/((c^(m+1)) (Sqrt[d+e (x^2)]))) Subst[∫(((a+b x))^n) ((Sinh[x])^m)dx,x,ArcSinh[c x]]

Program code:

Int[x_^m_*(a_.+b_.*ArcSinh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/c^(m+1)*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Subst[Int[(a+b*x)^n*Sinh[x]^m,x],x,ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[n,0] && IntegerQ[m]

3:  ∫(((((f x))^m) (a+b ArcSinh[c x]))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ m∉ℤ

Rule: If  e==(c^2) d ∧ m∉ℤ, then

∫(((((f x))^m) (a+b ArcSinh[c x]))/(Sqrt[d+e (x^2)]))dx  ⟶  
(((((f x))^(m+1)) (Sqrt[1+(c^2) (x^2)]) (a+b ArcSinh[c x]))/(f(m+1) (Sqrt[d+e (x^2)]))) Hypergeometric2F1[(1/2),((1+m)/2),((3+m)/2),-(c^2) (x^2)]-
((b c (((f x))^(m+2)) (Sqrt[1+(c^2) (x^2)]))/((f^2)(m+1) (m+2) (Sqrt[d+e (x^2)]))) HypergeometricPFQ[{1,1+(m/2),1+(m/2)},{(3/2)+(m/2),2+(m/2)},-(c^2) (x^2)]

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcSinh[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)/(f*(m+1))*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*(a+b*ArcSinh[c*x])*
    Hypergeometric2F1[1/2,(1+m)/2,(3+m)/2,-c^2*x^2] - 
  b*c*(f*x)^(m+2)/(f^2*(m+1)*(m+2))*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*
    HypergeometricPFQ[{1,1+m/2,1+m/2},{3/2+m/2,2+m/2},-c^2*x^2] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && Not[IntegerQ[m]]

2:  ∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n<-1

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcSinh[c x]))^n)/(Sqrt[1+(c^2) (x^2)]))==(∂_x)((((a+b ArcSinh[c x]))^(n+1))/(b c (n+1)))

Basis: If  e==(c^2) d, then (∂_x)(((((f x))^m) (Sqrt[1+(c^2) (x^2)]))/(Sqrt[d+e (x^2)]))==((f m (((f x))^(m-1)) (Sqrt[1+(c^2) (x^2)]))/(Sqrt[d+e (x^2)]))

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2) (x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ n<-1, then

∫(((((f x))^m) (((a+b ArcSinh[c x]))^n))/(Sqrt[d+e (x^2)]))dx  ⟶  
(((((f x))^m) (Sqrt[1+(c^2) (x^2)]) (((a+b ArcSinh[c x]))^(n+1)))/(b c (n+1) (Sqrt[d+e (x^2)])))-((f m (Sqrt[1+(c^2) (x^2)]))/(b c (n+1) (Sqrt[d+e (x^2)])))∫(((f x))^(m-1))(((a+b ArcSinh[c x]))^(n+1))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*ArcSinh[c_.*x_])^n_/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^m/(b*c*(n+1))*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*(a+b*ArcSinh[c*x])^(n+1) - 
  f*m/(b*c*(n+1))*Simp[Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]]*Int[(f*x)^(m-1)*(a+b*ArcSinh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && LtQ[n,-1]

4:  ∫(x^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ 2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ])

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p))==0

Basis: If  m∈ℤ, then (x^m) (((1+(c^2) (x^2)))^p)==(1/(b (c^(m+1)))) Subst[((Sinh[-(a/b)+(x/b)])^m) ((Cosh[-(a/b)+(x/b)])^(2p+1)),x,a+b ArcSinh[c x]] (∂_x)(a+b ArcSinh[c x])

Note: If  2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ]), then (x^n) ((Sinh[-(a/b)+(x/b)])^m) ((Cosh[-(a/b)+(x/b)])^(2p+1)) is integrable in closed-form.

Rule: If  e==(c^2) d ∧ 2 p+2∈(SuperPlus[ℤ])∧ m∈(SuperPlus[ℤ]), then

∫(x^m) (((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/(((1+(c^2) (x^2)))^p)) ∫(x^m) (((1+(c^2) (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/(b (c^(m+1)) (((1+(c^2) (x^2)))^p))) Subst[∫(x^n) ((Sinh[-(a/b)+(x/b)])^m) ((Cosh[-(a/b)+(x/b)])^(2p+1))dx,x,a+b ArcSinh[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c^(m+1))*Simp[(d+e*x^2)^p/(1+c^2*x^2)^p]*
    Subst[Int[x^n*Sinh[-a/b+x/b]^m*Cosh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcSinh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[e,c^2*d] && IGtQ[2*p+2,0] && IGtQ[m,0]

5:  ∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  when  e==(c^2) d ∧ p+(1/2)∈(SuperPlus[ℤ])∧ ((m+1)/2)∉(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  e==(c^2) d ∧ p+(1/2)∈(SuperPlus[ℤ])∧ ((m+1)/2)∉(SuperPlus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  ⟶  ∫((((a+b ArcSinh[c x]))^n)/(Sqrt[d+e (x^2)]))ExpandIntegrand[(((f x))^m) (((d+e (x^2)))^(p+(1/2))),x]dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcSinh[c*x])^n/Sqrt[d+e*x^2],(f*x)^m*(d+e*x^2)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[e,c^2*d] && IGtQ[p+1/2,0] && Not[IGtQ[(m+1)/2,0]] && (EqQ[m,-1] || EqQ[m,-2])

2.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  when  e≠ (c^2) d

1:  ∫x (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e≠ (c^2) d ∧ p≠-1

Derivation: Integration by parts

Basis:: If  p≠-1, then x (((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Rule: If  e≠ (c^2) d ∧ p≠-1, then

∫x (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  (((((d+e (x^2)))^(p+1)) (a+b ArcSinh[c x]))/(2 e (p+1)))-((b c)/(2 e (p+1)))∫((((d+e (x^2)))^(p+1))/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[x_*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcSinh[c*x])/(2*e*(p+1)) - b*c/(2*e*(p+1))*Int[(d+e*x^2)^(p+1)/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[e,c^2*d] && NeQ[p,-1]

2:  ∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  when  e≠ (c^2) d ∧ p∈ℤ ∧ (p>0 ∨ ((m-1)/2)∈(SuperPlus[ℤ])∧ m+p≤0)

Derivation: Integration by parts

Note: If  ((m-1)/2)∈(SuperPlus[ℤ])∧ p∈(SuperMinus[ℤ])∧ m+p≥0, then ∫(((f x))^m) (((d+e (x^2)))^p) is a rational function.

Rule: If  e≠ (c^2) d ∧ p∈ℤ ∧ (p>0 ∨ ((m-1)/2)∈(SuperPlus[ℤ])∧ m+p≤0), let  u=∫(((f x))^m) (((d+e (x^2)))^p)dx, then

∫(((f x))^m) (((d+e (x^2)))^p) (a+b ArcSinh[c x])dx  ⟶  u (a+b ArcSinh[c x])-b c∫(u/(Sqrt[1+(c^2) (x^2)]))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[a+b*ArcSinh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/Sqrt[1+c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && NeQ[e,c^2*d] && IntegerQ[p] && (GtQ[p,0] || IGtQ[(m-1)/2,0] && LeQ[m+p,0])

3:  ∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  when  e≠ (c^2) d ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If  e≠ (c^2) d ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ m∈ℤ, then

∫(((f x))^m)(((d+e (x^2)))^p)(((a+b ArcSinh[c x]))^n)dx  ⟶  ∫(((a+b ArcSinh[c x]))^n) ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcSinh[c*x])^n,(f*x)^m*(d+e*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && NeQ[e,c^2*d] && IGtQ[n,0] && IntegerQ[p] && IntegerQ[m]

U:  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

Rule:

∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx  ⟶  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^2)^p*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x]

Rules for integrands of the form (((h x))^m) (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)

1:  ∫(((h x))^m) (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  when  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ d>0 ∧ (g/e)<0

Derivation: Algebraic expansion

Basis: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ d>0 ∧ (g/e)<0, then (((d+e x))^p) (((f+g x))^q)==(((-(((d^2) g)/e)))^q) (((d+e x))^(p-q)) (((1+(c^2) (x^2)))^q)

Rule: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ d>0 ∧ (g/e)<0, then

∫(((h x))^m) (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  ⟶  (((-(((d^2) g)/e)))^q) ∫(((h x))^m) (((d+e x))^(p-q))(((1+(c^2) (x^2)))^q) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(h_.*x_)^m_.*(d_+e_.*x_)^p_*(f_+g_.*x_)^q_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (-d^2*g/e)^q*Int[(h*x)^m*(d+e*x)^(p-q)*(1+c^2*x^2)^q*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && EqQ[e*f+d*g,0] && EqQ[c^2*d^2+e^2,0] && HalfIntegerQ[p,q] && GeQ[p-q,0] && GtQ[d,0] && LtQ[g/e,0]

2:  ∫(((h x))^m) (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  when  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ ¬(d>0 ∧ (g/e)<0)

Derivation: Piecewise constant extraction

Basis: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0, then (∂_x)(((((d+e x))^q) (((f+g x))^q))/(((1+(c^2) (x^2)))^q))==0

Rule: If  e f+d g==0 ∧ (c^2) (d^2)+(e^2)==0 ∧ (p|q)∈ℤ+(1/2) ∧ p-q≥0 ∧ ¬(d>0 ∧ (g/e)<0), then

∫(((h x))^m) (((d+e x))^p) (((f+g x))^q) (((a+b ArcSinh[c x]))^n)dx  ⟶  
(((((-(((d^2) g)/e)))^(IntPart[q])) (((d+e x))^(FracPart[q])) (((f+g x))^(FracPart[q])))/(((1+(c^2) (x^2)))^(FracPart[q]))) ∫(((h x))^m) (((d+e x))^(p-q))(((1+(c^2) (x^2)))^q) (((a+b ArcSinh[c x]))^n)dx

Program code:

Int[(h_.*x_)^m_.*(d_+e_.*x_)^p_*(f_+g_.*x_)^q_*(a_.+b_.*ArcSinh[c_.*x_])^n_.,x_Symbol] :=
  (-d^2*g/e)^IntPart[q]*(d+e*x)^FracPart[q]*(f+g*x)^FracPart[q]/(1+c^2*x^2)^FracPart[q]*
    Int[(h*x)^m*(d+e*x)^(p-q)*(1+c^2*x^2)^q*(a+b*ArcSinh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && EqQ[e*f+d*g,0] && EqQ[c^2*d^2+e^2,0] && HalfIntegerQ[p,q] && GeQ[p-q,0]